Es besteht die Möglichkeit, den Robi softwaretechnisch fernzusteuern. Hierfür wird auf dem Robi eine Server-Applikation installiert, welche es erlaubt, Befehle im Klartext an den Robi zu senden. Der Robi liefert die entsprechenden Antworten ebenfalls in Klartext. Dies ermöglicht eine Bedienung über Software aber auch eine Bedienung durch eine Terminal-Anwendung wie beispielsweise putty.

Das Protokoll funktioniert nach dem Request-Response Prinzip wobei jeweils der Client die Requests stellt. Das Protokoll ist im Textformat entworfen. Dies ermöglicht die Überquerung von Plattformen, ohne dabei die Endianness oder andere Plattformspezifische Fragen beachten zu müssen. Da es sich um geringe Datenmengen handelt, ist der Overhead vertretbar. Als Voraussetzung für dieses Protokoll wird ein garantierter Übertragungskanal für Byte-Ströme angenommen wie ihn beispielsweise TCP zur Verfügung stellt.

Das Framing beschränkt sich auf eine Zeilenweise Trennung der einzelnen Requests und den jeweiligen Responses. Um das Protokoll möglichst zu vereinfachen wird auf eine Versionierung des Protokolls in Form eines spezifischen Startzeichens verzichtet. Als Antwort erhält der Aufrufer jeweils den Rückgabewert der aufgerufenen Methode. Liefert die Methode keinen Rückgabewert erhält der Aufrufer eine leere Zeile.

Eventuelle, transparente Erweiterung? Ist ein Aufruf nicht in Ordnung, so wird dem Aufrufer ein Fehlercode zurückgeliefert. In diesem Fall ist das erste Zeichen im Frame ein '*' gefolgt von einem numerischen Fehlercode. Optional kann ein erklärender Text auf den Fehlercode folgen.

Eine Beschreibung der möglichen Aufrufe befindet sich im Abschnitt Befehlssatz

Gültige Kommando

Request:  drive 10<CR><LF>
Response: <CR><LF>

Request:  getDistSensorValues<CR><LF>
Response: 10 0 12 45 100 200 312 450 35 35 32 31 32 31 30 30<CR><LF>

Ungültige Kommando

Request:  InvalidCommand<CR><LF>
Response: *1 Command Unknown<CR><LF>

Traffic  = Request | Response .
Request  = Command { Delimiter Parameter } FrameEnd .
Response = [ ReturnValue ] FrameEnd .

Command     = Token . 
Parameter   = FixedPoint | Integer .
ReturnValue = [ FixedPoint 
              | Integer 
              | ( "*" ErrorCode { Delimiter Token } ) ] . 

FixedPoint = Integer "." Digit { Digit } .
Integer    = "0" | ( [ "-" ] Number ) .
ErrorCode  = Number .
Token      = ( Grossbuchstabe | Kleinbuchstabe ) { AlphaNumerisch } .

AlphaNumerisch = Grossbuchstabe | Kleinbuchstabe | Digit .
Number         = NonZeroDigit { Digit } .
Grossbuchstabe =   "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" 
                 | "J" | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" 
                 | "S" | "T" | "U" | "V" | "W" | "X" | "Y" | "Z" .
Kleinbuchstabe =   "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" 
                 | "j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" 
                 | "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z" .
Digit          = "0" | NonZeroDigit .
NonZeroDigit   = "1" | "2" | "3" | "4" | "5" | "6"  | "7" | "8" | "9" .
Delimiter      = " " .
FrameEnd       = "\r" "\n" .